Funzioni di due variabili

Gianluca Gorni, Università di Udine. Ultima revisione: 31 marzo 2022.

Funzioni non continue o non differenziabili nell'origine

La funzione      f(x,y)=(((x^3)-3 x (y^2))/((Sqrt[(x^2)+(y^2)])^3))

È una funzione non continua nell'origine. Le curve di livello sono semirette per l'origine.

f0[x_,y_]:=(x^3-3x*y^2)/Sqrt[Abs[x^2+y^2]]^3;
ParametricPlot3D[{r*Cos[θ],r*Sin[θ],f0[r*Cos[θ],r*Sin[θ]]},{r,0.1,2},{θ,0,2Pi},Ticks->None]

La funzione       f(x,y)=(y/(Sqrt[(x^2)+(y^2)]))

È una funzione non continua nell'origine. Le curve di livello sono semirette per l'origine.

f1[x_,y_]:=y/Sqrt[x^2+y^2];
ParametricPlot3D[{r*Cos[θ],r*Sin[θ],f1[r*Cos[θ],r*Sin[θ]]},{r,0.001,2},{θ,0,2Pi},Ticks->None]

La funzione         f(x,y)=(Sqrt[(x^2)+(y^2)])

È una funzione continua ovunque ma non è differenziabile nell'origine

f[x_,y_]:=Sqrt[x^2+y^2];
ParametricPlot3D[{r*Cos[θ],r*Sin[θ],f[r*Cos[θ],r*Sin[θ]]},{r,0,1},{θ,0,2Pi},Ticks->None]

La funzione       f(x,y)=(((x^3)-3 x (y^2))/((x^2)+(y^2)))

È una funzione continua ovunque ma non è differenziabile nell'origine

g[x_,y_]:=(x^3-3x*y^2)/(x^2+y^2);
ParametricPlot3D[{r*Cos[θ],r*Sin[θ],g[r*Cos[θ],r*Sin[θ]]},{r,0.001,1},{θ,0,2Pi},Ticks->None]

Forme quadratiche

Caso definito positivo

paraboloide[x_,y_]:=x^2+y^2;
Show[{ParametricPlot3D[Evaluate[{{Cos[Pi/3],-Sin[Pi/3],0},{Sin[Pi/3],Cos[Pi/3],0},{0,0,1}}.{r*Cos[θ],2r*Sin[θ],paraboloide[r*Cos[θ],r*Sin[θ]]}],{r,0,2},{θ,0,2Pi},PlotPoints->{10,40},Ticks->None,PlotRange->{{-4,4},{-4,4},{0,4}},BoxRatios->{1,1,2/3}],Graphics3D[{Polygon[{{-4,-4,0},{4,-4,0},{4,4,0},{-4,4,0}}]}]}]

Caso definito negativo

paraboloide[x_,y_]:=x^2+y^2;
Show[{ParametricPlot3D[Evaluate[{{Cos[Pi/3],-Sin[Pi/3],0},{Sin[Pi/3],Cos[Pi/3],0},{0,0,1}}.{r*Cos[θ],2r*Sin[θ],-paraboloide[r*Cos[θ],r*Sin[θ]]}],{r,0,2},{θ,0,2Pi},PlotPoints->{10,40},Ticks->None,PlotRange->{{-4,4},{-4,4},{-4,1}},BoxRatios->{1,1,2/3}],Graphics3D[{EdgeForm[],Polygon[{{-4,-4,0},{0,0,0},{-4,4,0}}],Polygon[{{4,-4,0},{4,4,0},{-4,4,0}}]}]}]

Caso semidefinito positivo

With[{θ=Pi/6},
Show[{ParametricPlot3D[Evaluate[{{Cos[θ],-Sin[θ],0},{Sin[θ],Cos[θ],0},{0,0,1}}.{x,y,x^2}],{x,-2,2},{y,-2,2},PlotPoints->{15,2},Ticks->None,PlotRange->{{-3,3},{-3,3},All},BoxRatios->{1,1,2/3}],Graphics3D[{EdgeForm[],Polygon[{{-4,-4,0},{-4,4,0},{4,4,0},{4,-4,0},{-4,-4,0}}]}]}]]

Caso indefinito

Show[{Plot3D[x^2-y^2+2x*y,{x,-1,1},{y,-1,1},PlotPoints->{15,15},BoxRatios->{1,1,1}],Graphics3D[{Polygon[{{-2,-2,0},{2,-2,0},{2,2,0},{-2,2,0}}]}]},Ticks->None,PlotRange->{{-1,1},{-1,1},All}]

Massimi e minimi

Questa è la funzione da studiare:

f[x_,y_]:=2Log[2+x^2+y^2]-x*y;

Cerchiamo i punti critici:

Solve[{D[f[x,y],x],D[f[x,y],y]}==0,
{x,y},Reals]

La matrice hessiana in un punto generico:

MatrixForm[hessiana[x_,y_]=D[f[x,y],
{{x,y},2}]//Simplify]

La matrice hessiana nei punti critici:

hessiana[0,0]//MatrixForm

Det[hessiana[0,0]]

hessiana[1,1]//MatrixForm

Det[hessiana[1,1]]

hessiana[-1,-1]//MatrixForm

Det[hessiana[-1,-1]]

Il grafico di f disegnato con una griglia polare ellittica:

Show[{ParametricPlot3D[{3r*Cos[θ]+r*Sin[θ],3r*Cos[θ]-r*Sin[θ],f[3r*Cos[θ]+r*Sin[θ],3r*Cos[θ]-r*Sin[θ]]},{r,0,.5},{θ,0,2Pi},BoxRatios->{2,2,1.7}],Graphics3D[{PointSize[.03],Point[{1,1,f[1,1]}],Point[{-1,-1,f[-1,-1]}]}]}]